====== ファイル構成・定義 ======
[[erabasicリファレンス|リファレンストップ]] · [[erabasicリファレンス_総索引|名前の総索引]]
ERB・ERHの定義、マクロ、ファイルの構成を調べます。
===== #DEFINE =====
DEFINEマクロの宣言です。ERH中で使用することで、全ERBコード中の文字列をあらかじめ定義した別の文字列へ置換することができます。\\
詳しくはヘッダーファイル（ERH）を参照してください。\\
===== 特殊なブロックを表す行 =====
これらはプリプロセッサ行です。\\
これらを記述した同一行において、その直後に続けて命令や関数やコメントなどを記述してはいけません。\\
これらはeramakerでは解釈できないためコーディングするときに場合によっては;!;を使う必要があります。\\
===== [SKIPSTART] =====
===== [SKIPEND] =====
[SKIPSTART]から[SKIPEND]までの間に書いた行はEmueraでは読み込まれず実行されません。\\
これはEmueraとeramakerで挙動を意図的に変えたいときに使われるものです。\\
Emueraでは実行してほしくない文を記述する際に使ってください。\\
また、;!;と併用することで、Emuera以外では実行してほしくない文を記述することができます。\\
詳しくは一般の項目を参照してください。\\
===== [IF XXX] =====
===== [ELSEIF XXX] =====
===== [ELSE] =====
===== [ENDIF] =====
ある名称XXXのマクロが定義されているかどうかによって複数の行を実行するかどうか、分岐することができます。\\
詳しくはヘッダーファイル（ERH）を参照してください。\\
===== [IF_DEBUG] =====
===== [ENDIF] =====
[IF_DEBUG]から[ENDIF]までの間に書いた行はデバッグモード時のみ実行されます。\\
非デバッグモード時はコメント行と見なされ実行されません。\\
ただし、DEBUG系命令は元々非デバッグモード時には無視されるので、;#;を行頭に付ける必要はありません。\\
同様にデバッグ変数も非デバッグモード時には空文字列又は0のため、エラーの心配はありません。\\
デバッグモードについては[[erabasicリファレンス_デバッグ#デバッグモードの起動と操作|こちら]]を参照してください。\\
===== [IF_NDEBUG] =====
===== [ENDIF] =====
[IF_NDEBUG]から[ENDIF]までの間に書いた行は非デバッグモード時のみ実行されます。\\
デバッグモード時はコメント行と見なされ実行されません。\\
[IF_DEBUG]とは判定が逆になっています。\\
デバッグモードについては[[erabasicリファレンス_デバッグ#デバッグモードの起動と操作|こちら]]を参照してください。\\
----
===== ERHの広域変数・マクロ定義 =====
ERBフォルダの中には拡張子ERBのファイルのほか、拡張子ERHのファイルを置くことができます。\\
ERHファイルにはERBより先に処理すべき内容を記載します。\\
具体的には#DIM及び#DIMSによる広域変数の定義と#DEFINEによるマクロの定義です。\\
ヘッダー中に#DIM、#DIMSと#DEFINE以外の行を書いてはいけません。\\
EmueraはERBフォルダ内に置かれた*.ERHを全て読んでいきます。\\
処理順はcsvフォルダ内のファイル→*.ERH→*.ERBの順なのでERHの効果はCSVフォルダ内の記述には及びません。\\
逆に、_rename.csvによる置換は*.ERHにも適用されます。\\
eramakerEXは*.ERHには_rename.csvを適用しないため、ERHファイルを用いるとeramakerEXとの互換性は失われます。\\
==== 広域変数の宣言 ====
[[erabasicリファレンス_変数・定数・配列#変数の宣言・有効範囲|※ユーザー定義の変数]]も参照してください。\\
ヘッダーファイルでは新しい変数を宣言することができます。\\
これはERB中で宣言するプライベート変数とは異なり、ERB中の全ての箇所から参照できる広域変数になります。\\
プライベート変数とは異なりDYNAMIC、STATICの区別はなく、REFを用いた参照型変数を宣言することもできませんが、CONSTを用いた定数は同様に宣言できます。\\
宣言できる変数は3次元変数までを宣言することができます。\\
要素数を指定しない場合、要素数1の配列になるので非配列変数のように使うこともできます。\\
変数宣言は以下のように#DIM又は#DIMSにより行います。\\
なお、#DIM HOGE,1,2のようにすると二次元配列になります。\\
<*.ERH>
#DIM MY_INT
#DIM MY_INT_ARRAY, 100
#DIMS MY_STR
#DIMS MY_STR_ARRAY, 100
ERH中で上のように定義しておくことで、ERB中では\\
<*.ERB>
MY_INT = 100
MY_INT_ARRAY:10 = MY_INT_ARRAY:10 + 45
MY_STR = あああ
PRINTFORML {MY_INT_ARRAY:10} %MY_STR%
のように変数として使用できます。\\
#DIMによる変数宣言の要素数の指定は数値で行う他に定数式でも指定できます。\\
ただし、*.ERB中の#DIMと異なりマクロが展開されないことに注意してください。\\
=== SAVEDATA キーワード ===
変数宣言時にSAVEDATAキーワードを加えることでセーブされる変数が宣言できます。\\
ただしSAVEDATAキーワードを用いてセーブ可能な多次元変数を宣言する場合、オプション「セーブデータをバイナリ形式で保存する」が有効になっている必要があります。\\
<*.ERH>\\
#DIM SAVEDATA MY_INT_ARRAY, 100\\
#DIMS SAVEDATA MY_STR_ARRAY, 100\\
このように宣言することでMY_INT_ARRAY、MY_STR_ARRAYの内容はDAYやMONEYなどの既存変数と同様にセーブされロードされます。\\
逆に言えばSAVEDATAキーワードを付けずに宣言した変数はセーブされず、ロード時には初期化されます。\\
=== CHARADATA キーワード ===
変数宣言時にCHARADATAキーワードを加えることでキャラクタ変数が宣言できます。\\
CHARADATAはSAVEDATAキーワードと同時に使用することができます。\\
<*.ERH>
#DIM CHARADATA C_INT_ARRAY, 100
#DIMS CHARADATA C_STR_ARRAY, 100
#DIM CHARADATA SAVEDATA CS_INT_ARRAY, 100
上の例ではC_INT_ARRAY、C_STR_ARRAYはキャラクタ変数ですがセーブロードはされません。\\
CS_INT_ARRAYはキャラクタ変数であり、かつセーブもロードもされます。\\
=== GLOBAL キーワード ===
変数宣言時にGLOBALキーワードを加えることでグローバル変数が宣言できます。\\
GLOBALはSAVEDATAキーワードと同時に使用することができます。\\
<*.ERH>
#DIM GLOBAL G_INT_ARRAY, 100
#DIMS GLOBAL G_STR_ARRAY, 100
#DIM GLOBAL SAVEDATA GS_INT_ARRAY, 100
グローバル変数は通常のセーブロード時にはロードも初期化もされません。\\
この性質のため、異なるセーブデータ間でのデータの共有に使うことができます。\\
GLOBALとSAVEDATAキーワードを同時に使用した場合、SAVEGLOBAL, LOADGLOBAL命令によってglobal.savファイルに読み書きされる変数となります。\\
その他、初期値や定数化などの詳細はユーザー定義の変数を参照してください。\\
==== マクロの定義 ====
ここでいうマクロとはERBコード中の文字列を、あらかじめ定義した別の文字列へ置換する機能です。\\
マクロと名前は付いていますがEmueraの実行中にF1〜F12キーで使えるキーボードマクロとは関係ありません。\\
この機能はCやC++の#defineを参考に作られています。\\
ERHファイル中でマクロを定義することで全てのERBファイル内のコードに適用されます。\\
=== 基本的な使い方 ===
マクロは典型的には以下のように定義します。\\
<*.ERH>
#DEFINE <置換元識別子> <置換先式>
これでERB中で<置換元識別子>が<置換先式>に置換されます。 例えば、.ERH中で\\
<*.ERH>
#DEFINE FIVE 5
と定義しておくと、.ERB中のFIVEという文字列が5に置換されます。 例えば\\
<*.ERB>
X = FIVE
は\\
(展開後)\\
X = 5
と展開されます。\\
マクロには行末コメントをつけることもできます。\\
セミコロン以降はコメントとして無視されます。\\
セミコロン以降はマクロに含まれず、展開されることはありません。\\
<*.ERH>
#DEFINE FIVE 5 ;コメント
<*.ERB>
X = FIVE + FIVE
(展開後)
X = 5 + 5
マクロの展開はほぼ文字列そのままで行われることに注意してください。\\
<*.ERH>
#DEFINE SIX 1 + 5
#DEFINE NINE 8 + 1
<*.ERB>
X = SIX * NINE
はXに6*9、すなわち36が代入されると思うかもしれませんが、実際には\\
(展開後)
X = 1 + 5 * 8 + 1
と展開されるので掛け算が優先されて X = 42 になります。\\
マクロは"〜〜"など定数文字列にも展開できますし、変数や関数、式にもできます。\\
#DEFINEの右側の文字列がそのまま展開されると考えればだいたいのところは理解できるでしょう。\\
<*.ERH>
#DEFINE HOGE "ほげほげ"
#DEFINE PIYO A
#DEFINE FUGA DA:10
#DEFINE HOGERA LOCAL + MY_FUNC(X, Y)
<*.ERB>
X = STRLEN(HOGE)
Y = PIYO + 5
FUGA:20 += PIYO
LOCAL = HOGERA
@MY_FUNC(ARG, ARG:1)
#FUNCTION
〜略〜
(展開後)
X = STRLEN("ほげほげ")
Y = A + 5
DA:10:20 += A
LOCAL = LOCAL + MY_FUNC(X, Y)
@MY_FUNC(ARG, ARG:1)
#FUNCTION
〜略〜
マクロは文字列そのままで展開されるという仕様上、置換先を完結した式ではなく演算子や式の一部とすることもできます。\\
ただしこのような使い方は推奨しません。\\
よほど慎重に使わないとコードの可読性を著しく損ねることになります。\\
<*.ERH>
#DEFINE PLUS +
#DEFINE FIVEPLUS 5 +
<*.ERB>
X = 1 PLUS 2
Y = FIVEPLUS 2
(展開後)
X = 1 + 2
Y = 5 + 2
=== マクロの多重展開 ===
マクロを含むマクロを定義することができます。 そのようなマクロはERBのロード時にマクロが適用できなくなるまで多重展開されます。\\
<.ERH>
#DEFINE FIVE_1 5
#DEFINE FIVE_2 FIVE_1 + FIVE_1
#DEFINE FIVE_3 FIVE_2 + FIVE_2
<.ERB>
X = FIVE_3
(展開後)
X = 5 + 5 + 5 + 5
展開を一定回数繰り返してもマクロが残っている場合、Emueraは自己参照又は循環参照マクロの疑いありとして処理を打ち切り、エラー終了します。\\
以下のような自己参照又は循環参照するマクロを作ってしまわないように気をつけてください。\\
<.ERH>
#DEFINE HOGE HOGE
#DEFINE PIYO FUGA + 1
#DEFINE FUGA PIYO + 2
<.ERB>
;エラーになる
X = HOGE
Y = PIYO
=== プリプロセッサ ===
ある名称のマクロが定義されているかどうかによって複数の行を実行するかどうか、分岐することができます。\\
[IF XXX]行と[ENDIF]行の間の行はXXXがDEFINEされている場合のみ実行されます。 例えば以下のように使います\\
<*.ERB>
[IF HOGE]
PRINTL HOGEが定義されている
[ELSEIF PUYO]
PRINTL HOGEが定義されていない
PRINTL PUYOが定義されている
[ELSE]
PRINTL HOGEもPUYOも定義されていない
[ENDIF]
この目的のため、空のマクロ（置換先のないマクロ）も定義できます。\\
<*.ERH>
#DEFINE HOGE
=== マクロの制限 ===
マクロが展開されるのは基本的に式中のみです。\\
<*.ERH>
#DEFINE FIVE 5
<*.ERB>
PRINT FIVE
は単に"FIVE"の文字がPRINTされるだけです。\\
これは PRINT X がXの値ではなくXという文字をPRINTするだけなのと同じです。\\
マクロの置換先は代入演算子及び、代入演算子を含む式にすることはできません。\\
以下のマクロ定義はエラーになります。\\
<*.ERH>
;エラーになる
#DEFINE HOGE =
#DEFINE PUGE X = 1
マクロの置換先は式の部分でも可能だと書きましたが、括弧の対応だけはマクロの中で完結している必要があります。 以下のマクロ定義はエラーになります。\\
<*.ERH>
;エラーになる
#DEFINE HOGE ( X +
#DEFINE PUGE Y )
<*.ERB>
Z = HOGE PUGE
マクロの置換先を命令にすることはできません。\\
以下のマクロ定義はエラーになります。\\
<*.ERH>
#DEFINE MY_PRINTL PRINTL
<*.ERB>
MY_PRINTL これはPRINTLです
(展開後)
;エラーになる
前記の通り、マクロは*.ERBにのみ適用され、*.csvと*.ERHには適用されません。\\
また*.ERB内でもプリプロセッサ、属性名、及び行頭の記号には適用されません。\\
[SKIPSTART]など、#DIMや#FUNCTIONなど、@EVENTFIRSTなどの@の部分、は置換対象外です。\\
例えば#DEFINE HOGE SKIPSTART としても、[HOGE]でコメント化開始とはなりません。\\
ただし、#以降の文字列であっても#DIMの変数名などは置換対象になります。\\
例えば下記のコードは\\
<*.ERH>
#DEFINE HOGE MY_INT
#DEFINE FIVE 5
<*.ERB>
@FUNC
#DIM HOGE, FIVE
HOGE:0 = 10
(展開後)
@FUNC
#DIM MY_INT, 5
MY_INT:0 = 10
のように展開されるので正常に動作します。\\
==== CSVフォルダ ====
* キャラCSVの中に、Renameを適用可能。（オプションでONにしている場合のみ）